根据第一列，把第二列数据合并在一个单元格里面

参考

分组+一个去重 List.Distinct

let
    源 = Excel.CurrentWorkbook(){[Name="data"]}[Content],
    更改的类型 = Table.TransformColumnTypes(源,{{"宝贝名称", type text}, {"鞋码", type text}}),
    分组 = Table.Group(更改的类型, {"宝贝名称"}, {{"鞋码", each Text.Combine( List.Distinct( [鞋码] ),  ", ")  ,type text }})
in
    分组

@焦棚子 感谢大神，我会考虑购买你的课程。

@秋风一达 感谢你的考虑。

@焦棚子 老师好，如果是多列合并，请问怎么编辑代码呢

模拟数据在下面可以打开。
https://www.jianguoyun.com/p/Da6FIbMQo9yPBhi95rsEIAA

@秋风一达
你往后加一个，就好了。

let
    源 = Excel.CurrentWorkbook(){[Name="data1"]}[Content],
    更改的类型 = Table.TransformColumnTypes(源,{{"宝贝名称", type text}, {"鞋码", type text}, {"颜色", type text}}),
    自定义1 = Table.Group(更改的类型, 
        {"宝贝名称"}, {{"鞋码", each Text.Combine( List.Distinct( [鞋码] ),  ", ")  ,type text },
        {"颜色", each Text.Combine( List.Distinct( [颜色] ),  ", ")  ,type text }
        })
in
    自定义1

@焦棚子 老师好，我想给里面的鞋码列降序排序，请问怎么弄？
我是这样编辑的无法成功：
分组 = Table.Group(自定义1, {"宝贝名称"}, {{"鞋码", each Text.Combine(Table.Sort(List.Distinct( [鞋码]),{{"[鞋码]", Order.Descending}}), ",") ,type text }}),

模拟数据在下面可以打开。
https://www.jianguoyun.com/p/Da6FIbMQo9yPBhi95rsEIAA

@秋风一达

用 List.Sort不是 Table.Sort

let
  源 = Excel.CurrentWorkbook(){[Name = "表1"]}[Content], 
  类型 = Table.TransformColumnTypes(源, {{"宝贝名称", type text}, {"鞋码", type text}, {"颜色", type text}}), 
  结果 = Table.Group(
    类型, 
    {"宝贝名称"}, 
    {
      {"鞋码", each Text.Combine(List.Sort(List.Distinct([鞋码]), Order.Descending), ", "), type text}, 
      {"颜色", each Text.Combine(List.Distinct([颜色]), ", "), type text}
    }
  )
in
  结果