PowerQuery 获取 Word 文档文本内容

2019-10-13 11:02:17 ⋅ 2874 ⋅ 4 ⋅ 8

第一步定义一个自定义函数fx，关于office文档解析还可以参看https://pbihub.cn/blog/640：

let                                         
    fx = (path)=>                                           
let                                         
    Header = BinaryFormat.Record([                                          
        MiscHeader = BinaryFormat.Binary(14),                                           
        BinarySize = BinaryFormat.ByteOrder(BinaryFormat.UnsignedInteger32,0),                                          
        FileSize   = BinaryFormat.ByteOrder(BinaryFormat.UnsignedInteger32,0),                                          
        FileNameLen= BinaryFormat.ByteOrder(BinaryFormat.UnsignedInteger16,0),                                          
        ExtrasLen  = BinaryFormat.ByteOrder(BinaryFormat.UnsignedInteger16,0)]),                                            

    HeaderChoice = BinaryFormat.Choice(                                         
        BinaryFormat.ByteOrder(BinaryFormat.UnsignedInteger32,0),                                           
        each if _ <> 67324752 then BinaryFormat.Record([IsValid = false,Filename=null,Content=null])                                            
                              else BinaryFormat.Choice(BinaryFormat.Binary(26),      // Header payload - 14+4+4+2+2                                         
                                       each BinaryFormat.Record([IsValid  = true,                                           
                                                                 Filename = BinaryFormat.Text(Header(_)[FileNameLen]),                                          
                                                                 Extras   = BinaryFormat.Text(Header(_)[ExtrasLen]),                                            
                                                                 Content  = BinaryFormat.Transform(BinaryFormat.Binary(Header(_)[BinarySize]),                                          
                                                                                (x) => try Binary.Buffer(Binary.Decompress(x, Compression.Deflate)) otherwise null)                                         
                                                               ]),                                          
                        type binary)),                                          

    ZipFormat = BinaryFormat.List(HeaderChoice, each [IsValid]),                                            
    Entries=List.Transform(List.RemoveLastN(ZipFormat(File.Contents(path)),1),(e)=>[FileName=e[Filename],Content=e[Content]])                                           
in                                          
    Entries                                         
in                                          
fx

第二步调用函数：

let                                                 
    源 = Table.FromRecords(fx("C:\Users\Administrator\Desktop\测试.docx")),                                                    
    Content = 源{[FileName="word/document.xml"]}[Content],                                                   
    xml = Text.FromBinary(Content),                                                 
    data = Xml.Tables(xml){0}[Table]{0}[Table][r],                                                  
    txt = List.Transform(List.RemoveNulls(data),each Text.Combine(if [t]{0} is table then List.Transform([t],(x)=>x[#"Element:Text"]{0}) else [t]))                                                 
in                                                  
    txt

大家可以自行修改提取Word中的表格数据...

来广东玩啊，在一声声靓仔声中迷失自己......

查身份证归属地：
Json.Document(Web.Contents("https://api.guaqb.cn/music/id/card.php?id=430103199003081906"))

file

道高一尺魔高一丈
https://pbihub.cn/users/44

回复数量: 8

0086
⋅ 2019-10-23 10:28:58

这个太棒了。感谢，不过只能提纯文本，表格中文字没有提出来的。
0086
⋅ 2019-10-23 10:51:09

表格的话，好像要修改
data = Xml.Tables(xml){0}[Table]{0}[Table][r],
txt = List.Transform(List.RemoveNulls(data),each Text.Combine(if [t]{0} is table then List.Transform([t],(x)=>x[#"Element:Text"]{0}) else [t]))
in
txt

但现在没有改成功。
0086
⋅ 2019-10-23 11:30:33

以上代码如果文档是以表格开头的话，也提不到内容。

畅心你的问题其实爆照就能解决

⋅ 2019-10-25 09:08:25

@0086 假设需求是提取很多格式统一的简历信息，那么表格格式一般都是确认的：
我测试的表格用了三行八列，如下图所示

file
那么我的提取公式可以写为：

let                                                 
    源 = Table.FromRecords(fx("C:\Users\Administrator\Desktop\采购订单.docx")),                                                    
    Content = 源{[FileName="word/document.xml"]}[Content],                                                   
    xml = Text.FromBinary(Content),                                                 
    data = Table.Combine(Table.Combine(Xml.Tables(xml){[Name="body"]}[Table]{[Name="tbl"]}[Table]{[Name="tr"]}[Table][tc])[p])[r],
    TD=Table.PromoteHeaders(Table.FromRows(List.Split(List.Transform(data,each if _ is table then [t]{0} else _),8)))
in
    TD

畅心你的问题其实爆照就能解决
⋅ 2019-10-25 09:09:36
畅心你的问题其实爆照就能解决
⋅ 2019-10-25 10:15:55
注意当有多个表格时候的问题：
Xml.Tables(xml){[Name="body"]}[Table]{[Name="tbl"]}[Table]
此时的表格数据存储在不同的压缩集里面，你可以在此处修改行索引方式提取第几个表格，如提取第二个表格数据：
```
data=Table.Combine( Table.Combine(Xml.Tables(xml){[Name="body"]}[Table]{[Name="tbl"]}[Table]{1}[tr][tc])[p])[r],
TD=Table.PromoteHeaders(Table.FromRows(List.Split(List.Transform(TD,each if _ is table then Text.Combine([t]) else _),8)))
```

畅心你的问题其实爆照就能解决

⋅ 2019-10-25 14:46:04

假设一个word文档中存在纯文本和2个8列的表格：

let                                                 
    源 = Table.FromRecords(fx("C:\Users\Administrator\Desktop\采购订单.docx")),                                                    
    Content = 源{[FileName="word/document.xml"]}[Content],                                                   
    xml = Text.FromBinary(Content),
    TD= [文本=Text.Combine(List.Transform(List.RemoveNulls(Xml.Tables(xml){[Name="body"]}[Table]{[Name="p"]}[Table][r]),each Text.Combine(if [t]{0} is table then List.Transform([t],(x)=>x[#"Element:Text"]{0}) else [t])),"#(lf)"),
    表格=List.Transform(Xml.Tables(xml){[Name="body"]}[Table]{[Name="tbl"]}[Table][tr],each Table.PromoteHeaders(Table.FromRows(List.Split(List.Transform(Table.Combine(Table.Combine([tc])[p])[r],(x)=>if x is table then Text.Combine(x[t]) else x),8))))]
in
    TD

0086
⋅ 2019-10-30 11:05:15

谢谢分享！

请务必阅读并严格遵守《社区管理规范与使用说明》
支持 Markdown 格式, **粗体**、~~删除线~~、`单行代码`, 更多语法请见这里 Markdown 语法
支持表情，使用方法请见发送表情，可用的 Emoji 见 :metal: :point_right: Emoji 列表 :star: :sparkles:
上传图片, 支持拖拽和剪切板粘贴上传, 格式限制 - jpg, png, gif
不支持上传附件，请尽可能用文字和图片将问题描述清楚，如实在需要上传附件，可上传到共享网盘后分享链接
发布框支持本地存储功能，会在内容变更时保存，「提交」按钮点击时清空

请勿发布不友善或者负能量的内容。与人为善，比聪明更重要！

Ctrl+Enter

Power Query驾驶指南

请放肆的吹水

专栏文章（82）

作者：畅心

你的问题其实爆照就能解决

佛山

PowerQuery 获取 Word 文档文本内容

添加附言

Power Query驾驶指南

作者：畅心

专栏推荐