销售需求丨周分析

​咋说呢，白茶之前分享过关于月度环比、年同比、日环比的问题，有的小伙伴就问我说，咋不弄个周环比呢？白茶一寻思，也对！不差这一个！本期呢，白茶决定分享一下做周环比的思路。

先来看看本期的案例数据：

可以看得出来，这是一份日期不断档的数据，案例数据很简单。

（示例文件会放到知识星球中，小伙伴们可以搜索“PowerBI丨需求圈”，文章结尾处会有二维码。）

咱们先来思考一下思路。在DAX函数中，有过专门的时间智能函数，比如：XTD本期至今（年/季/月），TOTALMTD，TOTALQTD，TOTALYTD，但是唯独没有“周”这一说，很典型的中国式报表。要进行周分析，就必须要有周维度这个概念！说到这，相信小伙伴们已经反应过来了，添加日期表！

将数据导入到PowerBI中如下：

编写如下代码，生成日期表：

日期表 = 
GENERATE (
    CALENDAR ( MIN ( '示例'[日期] ), //注意：这里需要替换成你自己的数据
        MAX ( '示例'[日期] ) ),//注意：这里需要替换成你自己的数据
    VAR DA = [Date]
    VAR YEAR =
        YEAR ( DA )
    VAR QUARTER =
        "季度" & FORMAT ( DA, "Q" )
    VAR MONTE =
        FORMAT ( DA, "MM" ) & "月"
    VAR DAY =
        DAY ( DA )
    VAR WEEKID =
        WEEKDAY ( DA, 2 )
    VAR WEEKNUM =
        WEEKNUM ( DA, 2 )
    RETURN
        ROW (
            "年度", YEAR,
            "季度", QUARTER,
            "月份", MONTE,
            "日", DAY,
            "年度季度", YEAR & QUARTER,
            "年度月份", YEAR & MONTE,
            "星期", WEEKID,
            "年周", YEAR * 100 + WEEKNUM
        )
)

这里面涉及到一个新的函数→WEEKNUM函数。

这个函数，是根据DATE日期列，生成一个年度第几周的函数。

它的第二参数只有两个选项：1和2。

输入1表示周日是第一天。（国外的星期一）

输入2表示周一是第一天。（中国式报表）

生成的结果如下：

建立模型关系：

到这里，我们的准备工作基本完成。

开始编写代码：

聚合 = 
SUM ( '示例'[销售金额] )

周分析其实主要就是三点：上周同期、周累计、周环比的问题。

上周同期没啥好说的，白茶这里就不赘述了。

CALCULATE搭配DATEADD即可。

重点说说周累计：

本周至今WTD的代码如下：

WTD = 
VAR SELEYEARWEEK =
    SELECTEDVALUE ( '日期表'[年周] )
RETURN
    CALCULATE (
        [聚合],
        FILTER (
            ALL ( '日期表' ),
            '日期表'[年周] = SELEYEARWEEK
                && '日期表'[Date] <= MAX ( '日期表'[Date] )
        )
    )

结果如图：

怎么样，达到我们需要的每周累计的效果了吧？这里解释一下含义：

首先是定义常量，这里SELECTEDVALUE这个函数，会根据当前筛选上下文，获取当前数据，有点类似于智能匹配的赶脚。

然后呢，利用CALCULATE+FILTER的经典模式，聚合[年周]相同的销售数据，同时利用MAX进行判定，让数据的计算维持在事实表范围内，以免出现很多没有销售数据，但是出现累计的情况。

从而达到进行[年周]累计的效果。

那么上周累计呢？继续：

CTP WTD = 
VAR SELEYEAR =
    SELECTEDVALUE ( '日期表'[年度] )
VAR SELEYEARWEEK =
    SELECTEDVALUE ( '日期表'[年周] )
RETURN
    CALCULATE (
        [聚合],
        FILTER ( ALL ( '日期表' ), '日期表'[年度] = SELEYEAR && '日期表'[年周] = SELEYEARWEEK - 1 )
    )

结果如下：

小伙伴们看一下，同一个颜色框框内的数据是为一组，结果没有任何问题。这里面第二个SELE函数没啥好说的，周是按照顺序排的，减一下就是上周的。前面的SELE年度是为了给当前的计算圈定好当前的上下文，以免出现计算问题。（其实这里也可以去掉的，没有影响，但是小伙伴请记住这个，因为将来可能你用得到。比如说白茶使用的是[年周]，如果不使用年，只用第几周的概念，那么就很有必要限定年份。）

后面的就简单了，计算差额，求环比。

差额代码：

差额 = 
[WTD] - [CTP WTD]

环比代码：

周环比 = 
DIVIDE ( [差额], [CTP WTD] )

结果如图：

（BOSS：早点整出来多好！）

小伙伴们❤GET了么？

白茶会不定期的分享一些函数卡片

（文件在知识星球[PowerBI丨需求圈]）

这里是白茶，一个PowerBI的初学者。

下面这个知识星球是针对有实际需求的小伙伴，有需要的请加入下面的知识星球。

请在PC端查看，有部分图片无法在移动端显示。
PowerBI丨白茶