销售需求丨星级频次统计

在实际的销售情况中，经常能遇到为了销售而准备的销售活动，那么如何评价一次活动准备的是否成功呢？

首先我们需要知道的是这次活动的销售金额，还需要知道各个消费水平的消费人次，也就是对不同消费水平划分星级，进行频次统计。

那么该如何进行呢？跟着白茶的思路走。

来看看我们本次的案例数据：

一份产品信息表。

一份门店信息表。

一份销售事实表。

将其导入PowerBI中，系统会自动建立模型关系如下：

老规矩，添加我们的日期表：

日期表 = 
GENERATE (
    CALENDAR ( MIN ( '销售表'[订单日期] ), //注意：这里需要替换成你自己的数据
        MAX ( '销售表'[订单日期] ) ),//注意：这里需要替换成你自己的数据
    VAR DA = [Date]
    VAR YEAR =
        YEAR ( DA )
    VAR QUARTER =
        "季度" & FORMAT ( DA, "Q" )
    VAR MONTE =
        FORMAT ( DA, "MM" ) & "月"
    VAR DAY =
        DAY ( DA )
    VAR WEEKID =
        WEEKDAY ( DA, 2 )
    RETURN
        ROW (
            "年度", YEAR,
            "季度", QUARTER,
            "月份", MONTE,
            "日", DAY,
            "年度季度", YEAR & QUARTER,
            "年度月份", YEAR & MONTE,
            "星期", WEEKID
        )
)

结果如图：

建立相关的模型关系：

本次使用的案例数据相信小伙伴们比较熟悉，这是白茶使用频率最高的一组数据了。利用SUMX函数求出相关销售金额，编写如下代码：

销售金额 = 
SUMX ( '销售表', '销售表'[购买数量] * RELATED ( '产品表'[单价] ) )

将其放在不同维度的表格中，结果如图：

这样的话我们前期的准备工作就已经准备完毕了。

那么该如何对一定阶段的消费订单进行星级频次统计呢？

首先我们需要建立一个星级评价的维度：

在输入数据窗格下，添加我们的评价维度表（也可以在Excel中建立导入数据，都是可以的。），需要注意的是这个表不要与其他表格建立联系。

所有工作准备完毕，编写如下代码：

星级频次 = 
VAR CQ =
    MAX ( '日期表'[Date] )
VAR MI =
    SELECTEDVALUE ( '星级频次'[最小值] )
VAR MA =
    SELECTEDVALUE ( '星级频次'[最大值] )
VAR TA =
    SUMMARIZE (
        '销售表',
        '销售表'[订单号],
        "消费", CALCULATE ( [销售金额], FILTER ( ALL ( '日期表' ), '日期表'[Date] <= CQ ) )
    )
VAR HQ =
    CALCULATE ( COUNTROWS ( FILTER ( TA, [消费] <= MA && [消费] >= MI ) ) )
RETURN
    HQ

稍后白茶会解释一下各段含义，继续添加代码来检验我们代码的对错：

总行数 = 
COUNTROWS ( '销售表' )

将两个度量值同时展示，添加时间切片查看效果：

这样的话就达到了我们想要的需求，通过时间切片器来观测这段时间，各个消费级别的客户数量是多少。

可能有的小伙伴已经发现总计栏显示错误的问题了，这个一会儿再说，先来解释之前代码的含义：

CQ是为了选取最大的日期。因为白茶做的日期表是动态的，也就是当产生销售信息时，才会有日期产生，那么MAX选取的就是最新的日期。

MI和MA是为了对各个阶段的星级选取上下限的边界值。SELECTEDVALUE这个函数会智能匹配相关值。

TA是利用SUMMARIZE函数构建一个虚拟表，这个表只有两列，一列是[订单编号]，一列是该订单的[消费金额]。受限于CQ，匹配的相关数据只能是事实表中已有的，利用日期进行限定。

HQ是统计介于"星级表"最大值与最小值之间的个数，比如说大于0小于10000的出现过几次等等。

然后，在可视化表中确定当前上下文，就能根据当前日期范围统计各个阶段的人次了。

最后，来解决一下总计的问题，这里教大家一个通用的模式。

编写如下代码：

解决总计 = 
SUMX ( '星级频次', [星级频次] )

结果如下：

这次的总计结果没有任何问题，只需要利用SUMX函数的迭代特性，就可以解决这个问题。一般情况下，出现总计错误，嵌套一层SUMX函数即可。（不喜勿喷。）当然，也是有例外的。
（公众号回复：案例，获取本期数据。）

小伙伴们❤GET了么？

白茶会不定期的分享一些函数卡片

（文件在知识星球[PowerBI丨需求圈]）

这里是白茶，一个PowerBI的初学者。

下面这个知识星球是针对有实际需求的小伙伴，有需要的请加入下面的知识星球。

请在PC端查看，有部分图片无法在移动端显示。
PowerBI丨白茶